编程人员从大量的程序开发中积累了许多非常实用的经验与技巧，它们就象一盘盘的快餐，看似简单但营养绝对丰富！用“餐”之后，您的VB程序将立即超频。还犹豫什么，快来品尝品尝吧 ...
用Mid$命令超速字符串添加操作
大家都知道，&操作符的执行速度是相当慢的，特别是处理长字符串时。当必须重复地在同一变量上附加字符时，有一个基于Mid$命令的技巧可以使用。基本思路就是：预留一个足够长的空间存放操作的结果。下面是应用这个技术的一个例子。
假设要建立一个字符串，它要附加从1开始的10000个整数："1 2 3 4 5 6 7 ... 9999 10000"。下面是最简单的实现代码：
res = ""
For i = 1 to 10000: res = res & Str(i):
Next |
代码虽然简单，但问题也很明显：Res变量将被重分配10000次。下面的代码实现同样的目的，但效果明显好转：
Dim res As String
Dim i As Long
Dim index As Long
’预留足够长的缓冲空间
res = Space(90000)
’指针变量，指出在哪里插入字符串
index = 1
’循环开始
For i = 1 to 10000
substr = Str(i)
length = Len(substr)
’填充字符串的相应区间段数值
Mid$(res, index, length) = substr
’调整指针变量
index = index + length
Next
’删除多余字符
res = Left$(res, index - 1) |
测试表明：在一个333MHz的计算机上，前段代码执行时间为2.2秒，后者仅仅为0.08秒！代码虽然长了些，可是速度却提高了25倍之多。呵呵，由此看来：代码也不可貌相啊
从头开始删除集合项目
删除集合中的所有内容有许多方法，其中有些非常得迅速。来看看一个包含10,000个项目的集合：
Dim col As New Collection, i As Long
For i = 1 To 10000
col.Add i, CStr(i)
Next |
可以从末尾位置为起点删除集合内容，如下：
For i = col.Count To 1 Step -1
col.Remove i
Next |
也可以从开始位置为起点删除集合内容，如下：
For i = 1 To col.Count Step 1
col.Remove i
Next |
试验证明，后者要快于前者百倍多，比如0.06秒比4.1秒。原因在于：当引用接近末尾位置的集合项目时，VB必须要从第1个项目开始遍历整个的项目链。更有趣的是，如果集合项目的数量加倍，那么从末尾开始删除与从头开始删除，前者要比后者花费的时间将成倍增长，比如前者是24秒，后者可能为0.12秒这么短！
最后提醒您：删除集合的所有内容的最快方法就是“毁灭”它，使用下面的语句：
对于一个包含20,000个项目的集合，上述操作仅仅耗时0.05秒，这比使用最快的循环操作进行删除也要快2倍左右。
用InStr函数实现代码减肥
可以采用“旁门左道”的方式使用Instr函数实现代码的简练。下面是一个典型的例子，检测字符串中是否包含一个元音字母：
1、普通的方法：
If UCase$(char) = "A" Or UCase$(char) = "E" Or UCase$(char) = "I" Or UCase$(char) = "O" Or UCase$(char) = "U" Then
’ it is a vowel
End If |
2、更加简练的方法：
If InStr("AaEeIiOoUu", char) Then
’ it is a vowel
End If |
同样，通过单词中没有的字符作为分界符，使用InStr来检查变量的内容。下面的例子检查Word中是否包含一个季节的名字： 1、普通的方法：
If LCase$(word) = "winter" Or LCase$(word) = "spring" Or LCase$(word) = _ "summer" Or LCase$(word) = "fall" Then
’ it is a season’s name
End If |
2、更加简练的方法：
If Instr(";winter;spring;summer;fall;", ";" & word & ";") Then
’ it is a season’s name
End If |
有时候，甚至可以使用InStr来替代Select Case代码段，但一定要注意参数中的字符数目。下面的例子中，转换数字0到9的相应英文名称为阿拉伯数字：
1、普通的方法：
Select Case LCase$(word)
Case "zero"
result = 0
Case "one"
result = 1
Case "two"
result = 2
Case "three"
result = 3
Case "four"
result = 4
Case "five"
result = 5
Case "six"
result = 6
Case "seven"
result = 7
Case "eight"
result = 8
Case "nine"
result = 9
End Select |
2、更加简练的方法：
result = InStr(";zero;;one;;;two;;;three;four;;five;;six;;;seven;eight;nine;", _
";" & LCase$(word) & ";") \ 6 |
精用Boolean表达式，让代码再减肥
当设置基于表达式结果的Boolean型数值时，要避免使用多余的If/Then/Else语句结果。比如：
If SomeVar > SomeOtherVar Then
BoolVal = True
Else
BoolVal = False
End If |
上面这段代码就很烦琐，它们完全可以使用下面的一行代码来替代：
| BoolVal = (SomeVar > SomeOtherVar) |
括号不是必须的，但可以增加可读性。根据表达式中的操作数不同，后者比前者执行起来大约快50%到85%。后者中的括号对速度没有影响。
有时，使用这个技术实现代码的简练并非很明显。关键是要牢记：所有的比较操作结果或者是0（false），或者是－1（True）。所以，下面例子中的2段代码是完全相同的，但是第2段要运行得快些：
1、传统方法：
If SomeVar > SomeOtherVar Then
x = x + 1
End If |
2、更简练的方法
| x = x - (SomeVar > SomeOtherVar) |
函数名巧做局部变量
很多程序员都没有认识到“在函数本身中使用函数名”的妙处，这就象对待一个局部变量一样。应用这个技巧可以起到临时变量的作用，有时还能加速程序运行。看看下面的代码：
Function Max(arr() As Long) As Long
Dim res As Long, i As Long
res = arr(LBound(arr))
For i = LBound(arr) + 1 To UBound(arr)
If arr(i) > res Then res = arr(i)
Next
Max = res
End Function |
去掉res变量，使用函数名称本身这个局部变量，可以使程序更加简练：
Function Max(arr() As Long) As Long
Dim i As Long
Max = arr(LBound(arr))
For i = LBound(arr) + 1 To UBound(arr)
If arr(i) > Max Then Max = arr(i)
Next
End Function |
|
|
